week11

 week11_1_postman_saveStrings_loadStrings 這邊延續上週的程式碼加入下列程式 如果有讀到檔案 存到angles.txt內

  if(key=='r'){ //replay, 照著之前按 's' 存檔的 lines 重播一次

    if(R==0){

      String [] file = loadStrings("angles.txt");

        if(file != null){ //如果有讀到檔案

          for(int i=0;i<file.length;i++){

            lines.add(file[i]);

          }

        }

    }

week11_2_postman_alpha_interpolation 教了內插alpha的方法讓圖片可以根據儲存的檔案做動作

week11_2_postman_alpha_interpolation_better  另外設一個void myInterpolate() 把剛剛的程式碼加入 然後在draw 裡面 加入myInterpolate(); 讓儲存的圖片能夠自動動作看起來更順暢

//week11_3_postman_angin

//重新來一次,讓程式架構變更清楚

PImage postman, head, body, uparm1, hand1, uparm2, hand2, foot1, foot2;

void setup(){

  size(560,560);

  postman = loadImage("postman.png");

  head = loadImage("head.png");

  body = loadImage("body.png");

  uparm1 = loadImage("uparm1.png");

  hand1 = loadImage("hand1.png");

  uparm2 = loadImage("uparm2.png");

  hand2 = loadImage("hand2.png");

  foot1 = loadImage("foot1.png");

  foot2 = loadImage("foot2.png");

}

float [] angleX = new float[10]; //在3D的世界裡，我們的旋轉

float [] angleY = new float[10];

int ID = 0;

ArrayList<String> lines = new ArrayList<String>();

void keyPressed(){

  if(key=='s'){ //現在動作的所有關節,都存起來

    String now = "";//空字串

    for(int i=0;i<10;i++){

      now += angleX[i] + " ";

      now += angleY[i] + " ";

    }

    lines.add(now);

    String [] arr = new String[lines.size()];

    lines.toArray(arr);

    saveStrings("angles.txt",arr);

    println("現在存檔:"+now);

  }

  if(key=='r'){

    String [] file = loadStrings("angles.txt");

    if(file != null){ //如果有讀到檔案

      for(int i=0;i<file.length;i++){

        lines.add(file[i]);

        println("現在讀檔:"+file[i]);

      }

    }

  }

  if(key=='p') playing = !playing; //播動畫 <=> 不播動畫 

  if(key=='1') ID = 1; // 左邊臂

  if(key=='2') ID = 2; // 左邊手

  if(key=='3') ID = 3; // 右邊臂

  if(key=='4') ID = 4; // 右邊手

  if(key=='5') ID = 5; // 左邊腳

  if(key=='6') ID = 6; // 右邊腳

  if(key=='0') ID = 0; // 頭

}

boolean playing = false;

void mouseDragged(){

  angleX[ID] += mouseX - pmouseX;

  angleY[ID] += mouseY - pmouseY;

}

int R = 0;

void myInterpolate(){

  if(lines.size()>=2){

    float alpha = (frameCount%30)/30.0; //介於0.0~1.0中間的值

    if(alpha==0.0) R = (R+1)%lines.size();

    int R2 = (R+1)%lines.size();

    float [] oldAngle = float(split( lines.get( R ), ' '));

    float [] newAngle = float(split( lines.get( R2 ), ' '));

    for(int i=0;i<10;i++){

      angleX[i] = oldAngle[i*2+0]*(1-alpha) + newAngle[i*2+0]*alpha;

      angleY[i] = oldAngle[i*2+1]*(1-alpha) + newAngle[i*2+1]*alpha;

    }

  }

}

void draw(){

  background(#FFFFF2);

  if(playing) myInterpolate();

  image(body,0,0);

  pushMatrix();

    translate(232,200);

    rotate(radians(angleX[0]));

    translate(-232,-200);

    image(head,0,0);

  popMatrix();

  

  pushMatrix();

    translate(220,375);

    rotate(radians(angleX[5]));

    translate(-220,-375);

    image(foot1,0,0);

  popMatrix();

  

  pushMatrix();

    translate(260,372);

    rotate(radians(angleX[6]));

    translate(-260,-372);

    image(foot2,0,0);

  popMatrix();

  

  pushMatrix(); // 要畫左邊的上手臂、手肘

    translate(+185, +261);

    rotate(radians(angleX[1]));

    translate(-185, -261);

    image(uparm1, 0, 0); // 上手臂

    pushMatrix();

      translate(+116, +265);

      rotate(radians(angleX[2]));

      translate(-116, -265);

      image(hand1, 0, 0);

    popMatrix();

  popMatrix();

  

  pushMatrix(); // 要畫右邊的上手臂、手肘

    translate(290, 262);

    rotate(radians(angleX[3]));

    translate(-290, -262);

    image(uparm2, 0, 0);

    pushMatrix();

      translate(357, 259);

      rotate(radians(angleX[4]));

      translate(-357, -259);

      image(hand2, 0, 0);

    popMatrix();

  popMatrix();

}