2025年4月25日 星期五

12750512-林政杰-week10

 week10-1

程式碼:

//week10-1_postman

//頭、身體、手臂、手肘、腳

size(560,560);

PImage postman=loadImage("postman.png");

PImage head=loadImage("head.png");

PImage body =loadImage("body.png");

background(#FFFFF2);

image(postman,0,0);//基礎的的郵差先生

fill(255,0,255,128);//半透明的紫色

rect(0,0,560,560);//蓋上去

image(head,0,0);//再畫頭

image(body,0,0);//再畫身體


week10-2





















程式碼:

//week10-2_postman_head_body_push_trt
//頭、身體、手臂、手肘、腳
PImage postman,head,body;
void setup(){
  size(560,560);
  postman =loadImage("postman.png");
  head =loadImage("head.png");
  body=loadImage("body.png");
}
void draw(){
  background(#FFFFF2);
  image(postman,0,0);//基礎的的郵差先生
  fill(255,0,255,128);//半透明的紫色
  rect(0,0,560,560);//蓋上去
  pushMatrix();
    translate(+232,+231);//再放回去正確的位置
    rotate(radians(mouseX));
    translate(-232,-231);//把頭的旋轉中心放到(0,0)
    image(head,0,0);//再畫頭
  popMatrix();
  image(body,0,0);//再畫身體
}



































week10-3

程式碼:
//week10-3_postman_head_body_uparm1_hand1_push_trt_pop
//頭、身體、手臂、手肘、腳
PImage postman,head,body,uparm1,hand1;
void setup(){
  size(560,560);
  postman =loadImage("postman.png");
  head =loadImage("head.png");
  body=loadImage("body.png");
  uparm1=loadImage("uparm1.png");
  hand1=loadImage("hand1.png");
}
void draw(){
  background(#FFFFF2);
  image(postman,0,0);//基礎的的郵差先生(全身)
  fill(255,0,255,128);//半透明的紫色
  rect(0,0,560,560);//蓋上去
  pushMatrix();//要畫左邊的上手臂、手肘
    translate(+185,+261);
    //rotate(radians(mouseX));
    translate(-185,-261);
    image(uparm1,0,0);//上手臂
    pushMatrix();
      translate(+116,+265);//再放回去正確的位置
      rotate(radians(mouseX));
      translate(-116,-265);//把頭的旋轉中心放到(0,0)
      image(hand1,0,0);//再畫頭
    popMatrix();
  popMatrix();
}

week10-4

程式碼:
// week10_4_postman_head_body_uparm1_hand1_uparm2_hand2_push_trt_pop
PImage postman,head,body,uparm1,hand1,uparm2,hand2;
void setup(){
  size(560,560);
  postman = loadImage("postman.png");
  head = loadImage("head.png");
  body = loadImage("body.png");
  uparm1 = loadImage("uparm1.png");
  hand1 = loadImage("hand1.png");
  uparm2 = loadImage("uparm2.png");
  hand2 = loadImage("hand2.png");
}
void draw(){
  background(#FFFFF2);
  image(postman,0,0); // 基礎郵差(全身)
  fill(255,0,255,128); //半透明的紫色
  rect(0,0,560,560); //蓋上去
  pushMatrix(); //要畫左邊的手臂、手肘
    translate(+185,+261);
    //rotate(radians(mouseX));
    translate(-185,-261);
    image(uparm1,0,0);//上手臂
    pushMatrix();
      translate(+116,+265);
      rotate(radians(mouseX));
      translate(-116,-265);
      image(hand1,0,0);
    popMatrix();
  popMatrix(); //畫右邊的上手臂、手肘
  pushMatrix();
    translate(+290,+262);
    //rotate(radians(mouseX));
    translate(-290,-262);
    image(uparm2,0,0);//上手臂
    pushMatrix();
      translate(+367,+259);
      rotate(radians(mouseX));
      translate(-367,-259);
      image(hand2,0,0);
    popMatrix();
  popMatrix();
  pushMatrix();
    translate(+232,+200); // 再放回正確的位置
    rotate(radians(mouseX));
    translate(-232,-200); // 把頭的旋轉中心,放到(0,0)
    image(head,0,0); //再畫頭
  popMatrix();
   image(body,0,0); //再畫身體
}
























week10-5

程式碼:
// week10_5_postman_many_angle_ID_mouseDragged
PImage postman, head, body, uparm1, hand1, uparm2, hand2;
float [] angle = new float[20]; // 準備20個關節的變數
int ID = 0; // 現在要處理的關節 ID (第幾個關節)
void mouseDragged(){
  angle[ID] += mouseX - pmouseX;
}
void keyPressed(){
  if(key=='1') ID = 1; // 左邊臂
  if(key=='2') ID = 2; // 左邊手
  if(key=='3') ID = 3; // 右邊臂
  if(key=='4') ID = 4; // 右邊手
  if(key=='5') ID = 5; // (待用)
  if(key=='6') ID = 6; // (待用)
  if(key=='0') ID = 0; // 頭
}
void setup(){
  size(560, 560);
  postman = loadImage("postman.png");
  head = loadImage("head.png");
  body = loadImage("body.png");
  uparm1 = loadImage("uparm1.png");
  hand1 = loadImage("hand1.png");
  uparm2 = loadImage("uparm2.png");
  hand2 = loadImage("hand2.png");
}
void draw(){
  background(#FFFFF2);
  image(postman, 0, 0); // 基礎的(全身)
  fill(255, 0, 255, 128); // 半透明的紫色
  rect(0, 0, 560, 560); // 蓋上去
  pushMatrix(); // 要畫左邊的上手臂、手肘
    translate(+185, +261);
    rotate(radians(angle[1]));
    translate(-185, -261);
    image(uparm1, 0, 0); // 上手臂
    pushMatrix();
      translate(+116, +265);
      rotate(radians(angle[2]));
      translate(-116, -265);
      image(hand1, 0, 0);
    popMatrix();
  popMatrix();
  
  pushMatrix(); // 要畫右邊的上手臂、手肘
    translate(290, 262);
    rotate(radians(angle[3]));
    translate(-290, -262);
    image(uparm2, 0, 0);
    pushMatrix();
      translate(357, 259);
      rotate(radians(angle[4]));
      translate(-357, -259);
      image(hand2, 0, 0);
    popMatrix();
  popMatrix();
  
  pushMatrix();
    translate(+236, +231); // 再放回去正確的位置
    rotate(radians(angle[0]));
    translate(-236, -231); // 把頭的旋轉中心, 放到(0,0)
    image(head, 0, 0); // 再畫頭
  popMatrix();
  image(body, 0, 0); // 再畫身體
}

week10-6

程式碼:
//week10_6_postman_manyangle_ID_saveStrings_loadStrings
PImage head,postman,body,hand1,uparm1,hand2,uparm2;
float [] angle = new float[20];//20個關節變數
int ID = 0;//處理中關節ID
void mouseDragged(){
   angle[ID]+=mouseX-pmouseX; 
}
void keyPressed(){
    if(key=='1') ID = 1; // 左臂
    if(key=='2') ID = 2; // 左手
    if(key=='3') ID = 3; // 右臂
    if(key=='4') ID = 4; // 右手
    if(key=='5') ID = 5; // (待用)
    if(key=='6') ID = 6; // (待用)
    if(key=='0') ID = 0; // 頭
    

    if(key=='s'){//每按一次S就存一組ANGLE
      String now="";//要放現在全部關節的值
      for(int i=0;i<20;i++){
         now+=angle[i]+" "; //全部塞到now裡
      }
      lines.add(now);//現在的這行加到lines裡
      String[] arr= new String[lines.size()];
      lines.toArray(arr);
      saveStrings("angles.txt",arr);
    }
  if(key=='r'){//讀入
    if(R<lines.size()){
       float [] now=float(split(lines.get(R),' '));// 把字串拆成角度陣列
       for(int i=0;i<20;i++)  angle[i]=now[i];// 套用到每個角度
       R=(R+1)%lines.size();
    }
   }  
}
int R=0;// 回放用的索引
ArrayList<String> lines = new ArrayList<String>();//放移動結果 
void setup(){
  size(560,560);
  postman= loadImage("postman.png");
  head =loadImage("head.png");
  body =loadImage("body.png");
  uparm1=loadImage("uparm1.png");
  hand1=loadImage("hand1.png");
  uparm2=loadImage("uparm2.png");
  hand2=loadImage("hand2.png");
}
void draw(){// 每一幀會自動畫一次（畫出角色與角度）
  background(#FFFFF2);
  image(postman,0,0);
  fill(255,0,255,128);
  rect(0,0,560,560);
  // 左手臂（上臂＋手）
  pushMatrix();
    translate(185,261);
    rotate(radians(angle[1]));
    translate(-185,-261);
    image(uparm1,0,0);
    pushMatrix();
      translate(116,265);
      rotate(radians(angle[2]));
      translate(-116,-265);
      image(hand1,0,0);
    popMatrix();
  popMatrix();
  // 右手臂（上臂＋手）
  pushMatrix();
    translate(290,262);
    rotate(radians(angle[3]));
    translate(-290,-262);
    image(uparm2,0,0);
    pushMatrix();
      translate(357,259);
      rotate(radians(angle[4]));
      translate(-357,-259);
      image(hand2,0,0);
    popMatrix();
  popMatrix();
  // 頭部
  pushMatrix();
    translate(236,231);//再放回去正確位置
    rotate(radians(angle[0]));
    translate(-236,-231);//把頭的旋轉中心放到(0,0)
    image(head,0,0);
  popMatrix();
  image(body,0,0);
}        


















於
標籤： ,

沒有留言:

張貼留言

訂閱： 張貼留言 (Atom)